English | >> Français << | Deutsch | Magyar | 中文 | Polski ZVON > Tutorials > XSLT Tutorial
>> Page 70 << | Précédent | Suivant | Contenu | Index des éléments

Vous pouvez utiliser l'élément xsl:apply-imports pour extraire les informations d'un modèle importé dont vous modifiez le comportement. Feuille de style XSLT 2 importe Feuille de style XSLT 1 et se substitue à son modèle. Feuille de style XSLT 3 importe Feuille de style XSLT 1 et modifie son modèle. L'élément xsl-apply-imports ne s'applique qu'aux modèles importés avec l'élément xsl:import, et pas aux modèles inclus avec l'élément xsl:include ( Feuille de style XSLT 4 ).

Feuille de style XSLT 1

Source XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Sortie
<DIV style="color:red">AAA</DIV>

<DIV style="color:red">BBB</DIV>

<DIV style="color:red">CCC</DIV>

Vue HTML
AAA
BBB
CCC
Feuille de style XSLT (file: id2.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:template match="/*/*">
     <DIV style="color:red">
          <xsl:value-of select="name()"/>
     </DIV>
</xsl:template>


</xsl:stylesheet>


Feuille de style XSLT 2

Source XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Sortie
<EM>AAA</EM>

<EM>BBB</EM>

<EM>CCC</EM>

Vue HTML
AAA BBB CCC
Feuille de style XSLT (file: id3.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:import href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:value-of select="name()"/>
     </EM>
</xsl:template>


</xsl:stylesheet>


Feuille de style XSLT 3

Source XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Sortie
<EM>
  <DIV style="color:red">AAA</DIV>
</EM>

<EM>
  <DIV style="color:red">BBB</DIV>
</EM>

<EM>
  <DIV style="color:red">CCC</DIV>
</EM>

Vue HTML
AAA
BBB
CCC
Feuille de style XSLT (file: id4.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:import href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:apply-imports/>
     </EM>
</xsl:template>


</xsl:stylesheet>


Feuille de style XSLT 4

Source XML
<source>

<AAA/>
<BBB/>
<CCC/>

</source>

Sortie
<EM/>

<EM/>

<EM/>

Vue HTML
Feuille de style XSLT (file: id5.xsl )
<xsl:stylesheet version = '1.0'
     xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>

<xsl:include href="id2.xsl"/>
<xsl:template match="/*/*">
     <EM>
          <xsl:apply-imports/>
     </EM>
</xsl:template>


</xsl:stylesheet>