Search    TOC: Show / Hide

   Indexes: Functions / Variables / Commands / Forms / Options / Macros / Keywords / Misc

   Next: Documentation   Previous: Keymaps   

24. Major and Minor Modes


A mode is a set of definitions that customize Emacs and can be turned on and off while you edit. There are two varieties of modes: major modes, which are mutually exclusive and used for editing particular kinds of text, and minor modes, which provide features that users can enable individually.

This chapter describes how to write both major and minor modes, how to indicate them in the mode line, and how they run hooks supplied by the user. For related topics such as keymaps and syntax tables, see section Keymaps, and section Syntax Tables.


top next
24.1. Major Modes

Major modes specialize Emacs for editing particular kinds of text. Each buffer has only one major mode at a time.

The least specialized major mode is called Fundamental mode. This mode has no mode-specific definitions or variable settings, so each Emacs command behaves in its default manner, and each option is in its default state. All other major modes redefine various keys and options. For example, Lisp Interaction mode provides special key bindings for C-j (eval-print-last-sexp), TAB (lisp-indent-line), and other keys.

When you need to write several editing commands to help you perform a specialized editing task, creating a new major mode is usually a good idea. In practice, writing a major mode is easy (in contrast to writing a minor mode, which is often difficult).

If the new mode is similar to an old one, it is often unwise to modify the old one to serve two purposes, since it may become harder to use and maintain. Instead, copy and rename an existing major mode definition and alter the copy--or define a derived mode (see section Defining Derived Modes). For example, Rmail Edit mode, which is in `emacs/lisp/rmailedit.el', is a major mode that is very similar to Text mode except that it provides three additional commands. Its definition is distinct from that of Text mode, but was derived from it.

Rmail Edit mode offers an example of changing the major mode temporarily for a buffer, so it can be edited in a different way (with ordinary Emacs commands rather than Rmail commands). In such cases, the temporary major mode usually has a command to switch back to the buffer's usual mode (Rmail mode, in this case). You might be tempted to present the temporary redefinitions inside a recursive edit and restore the usual ones when the user exits; but this is a bad idea because it constrains the user's options when it is done in more than one buffer: recursive edits must be exited most-recently-entered first. Using an alternative major mode avoids this limitation. See section Recursive Editing.

The standard GNU Emacs Lisp library directory contains the code for several major modes, in files such as `text-mode.el', `texinfo.el', `lisp-mode.el', `c-mode.el', and `rmail.el'. You can study these libraries to see how modes are written. Text mode is perhaps the simplest major mode aside from Fundamental mode. Rmail mode is a complicated and specialized mode.

top 24.1.1. Major Mode Conventions

The code for existing major modes follows various coding conventions, including conventions for local keymap and syntax table initialization, global names, and hooks. Please follow these conventions when you define a new major mode:

top 24.1.2. Major Mode Examples

Text mode is perhaps the simplest mode besides Fundamental mode. Here are excerpts from `text-mode.el' that illustrate many of the conventions listed above:

;; Create mode-specific tables.
(defvar text-mode-syntax-table nil 
  "Syntax table used while in text mode.")

(if text-mode-syntax-table
    ()              ; Do not change the table if it is already set up.
  (setq text-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?\" ".   " text-mode-syntax-table)
  (modify-syntax-entry ?\\ ".   " text-mode-syntax-table)
  (modify-syntax-entry ?' "w   " text-mode-syntax-table))

(defvar text-mode-abbrev-table nil
  "Abbrev table used while in text mode.")
(define-abbrev-table 'text-mode-abbrev-table ())

(defvar text-mode-map nil)   ; Create a mode-specific keymap.

(if text-mode-map
    ()              ; Do not change the keymap if it is already set up.
  (setq text-mode-map (make-sparse-keymap))
  (define-key text-mode-map "\t" 'indent-relative)
  (define-key text-mode-map "\es" 'center-line)
  (define-key text-mode-map "\eS" 'center-paragraph))

Here is the complete major mode function definition for Text mode:

(defun text-mode ()
  "Major mode for editing text intended for humans to read@enddots{}
 Special commands: \\{text-mode-map}
Turning on text-mode runs the hook `text-mode-hook'."
  (interactive)
  (kill-all-local-variables)
  (use-local-map text-mode-map)
  (setq local-abbrev-table text-mode-abbrev-table)
  (set-syntax-table text-mode-syntax-table)
  (make-local-variable 'paragraph-start)
  (setq paragraph-start (concat "[ \t]*$\\|" page-delimiter))
  (make-local-variable 'paragraph-separate)
  (setq paragraph-separate paragraph-start)
  (setq mode-name "Text")
  (setq major-mode 'text-mode)
  (run-hooks 'text-mode-hook))      ; Finally, this permits the user to
                                    ;   customize the mode with a hook.

The three Lisp modes (Lisp mode, Emacs Lisp mode, and Lisp Interaction mode) have more features than Text mode and the code is correspondingly more complicated. Here are excerpts from `lisp-mode.el' that illustrate how these modes are written.

;; Create mode-specific table variables.
(defvar lisp-mode-syntax-table nil "")  
(defvar emacs-lisp-mode-syntax-table nil "")
(defvar lisp-mode-abbrev-table nil "")

(if (not emacs-lisp-mode-syntax-table) ; Do not change the table
                                       ;   if it is already set.
    (let ((i 0))
      (setq emacs-lisp-mode-syntax-table (make-syntax-table))

      ;; Set syntax of chars up to 0 to class of chars that are
      ;;   part of symbol names but not words.
      ;;   (The number 0 is 48 in the ASCII character set.)
      (while (< i ?0) 
        (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
        (setq i (1+ i)))
      ...
      ;; Set the syntax for other characters.
      (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
      ...
      (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
      ...))
;; Create an abbrev table for lisp-mode.
(define-abbrev-table 'lisp-mode-abbrev-table ())

Much code is shared among the three Lisp modes. The following function sets various variables; it is called by each of the major Lisp mode functions:

(defun lisp-mode-variables (lisp-syntax)
  (cond (lisp-syntax
      (set-syntax-table lisp-mode-syntax-table)))
  (setq local-abbrev-table lisp-mode-abbrev-table)
  ...

Functions such as forward-paragraph use the value of the paragraph-start variable. Since Lisp code is different from ordinary text, the paragraph-start variable needs to be set specially to handle Lisp. Also, comments are indented in a special fashion in Lisp and the Lisp modes need their own mode-specific comment-indent-function. The code to set these variables is the rest of lisp-mode-variables.

  (make-local-variable 'paragraph-start)
  (setq paragraph-start (concat page-delimiter "\\|$" ))
  (make-local-variable 'paragraph-separate)
  (setq paragraph-separate paragraph-start)
  ...
  (make-local-variable 'comment-indent-function)
  (setq comment-indent-function 'lisp-comment-indent))

Each of the different Lisp modes has a slightly different keymap. For example, Lisp mode binds C-c C-z to run-lisp, but the other Lisp modes do not. However, all Lisp modes have some commands in common. The following code sets up the common commands:

(defvar shared-lisp-mode-map ()
  "Keymap for commands shared by all sorts of Lisp modes.")

(if shared-lisp-mode-map
    ()
   (setq shared-lisp-mode-map (make-sparse-keymap))
   (define-key shared-lisp-mode-map "\e\C-q" 'indent-sexp)
   (define-key shared-lisp-mode-map "\177"
               'backward-delete-char-untabify))

And here is the code to set up the keymap for Lisp mode:

(defvar lisp-mode-map ()
  "Keymap for ordinary Lisp mode@enddots{}")

(if lisp-mode-map
    ()
  (setq lisp-mode-map (make-sparse-keymap))
  (set-keymap-parent lisp-mode-map shared-lisp-mode-map)
  (define-key lisp-mode-map "\e\C-x" 'lisp-eval-defun)
  (define-key lisp-mode-map "\C-c\C-z" 'run-lisp))

Finally, here is the complete major mode function definition for Emacs Lisp mode.

(defun lisp-mode ()
  "Major mode for editing Lisp code for Lisps other than GNU Emacs Lisp.
Commands:
Delete converts tabs to spaces as it moves back.
Blank lines separate paragraphs.  Semicolons start comments.
\\{lisp-mode-map}
Note that `run-lisp' may be used either to start an inferior Lisp job
or to switch back to an existing one.

Entry to this mode calls the value of `lisp-mode-hook'
if that value is non-nil."
  (interactive)
  (kill-all-local-variables)
  (use-local-map lisp-mode-map)          ; Select the mode's keymap.
  (setq major-mode 'lisp-mode)           ; This is how describe-mode
                                         ;   finds out what to describe.
  (setq mode-name "Lisp")                ; This goes into the mode line.
  (lisp-mode-variables t)                ; This defines various variables.
  (setq imenu-case-fold-search t)
  (set-syntax-table lisp-mode-syntax-table)
  (run-hooks 'lisp-mode-hook))           ; This permits the user to use a
                                         ;   hook to customize the mode.

top 24.1.3. How Emacs Chooses a Major Mode

Based on information in the file name or in the file itself, Emacs automatically selects a major mode for the new buffer when a file is visited. It also processes local variables specified in the file text.

topCommand: fundamental-mode
Fundamental mode is a major mode that is not specialized for anything in particular. Other major modes are defined in effect by comparison with this one--their definitions say what to change, starting from Fundamental mode. The fundamental-mode function does not run any hooks; you're not supposed to customize it. (If you want Emacs to behave differently in Fundamental mode, change the global state of Emacs.)


topCommand: normal-mode &optional find-file
This function establishes the proper major mode and buffer-local variable bindings for the current buffer. First it calls set-auto-mode, then it runs hack-local-variables to parse, and bind or evaluate as appropriate, the file's local variables.

If the find-file argument to normal-mode is non-nil, normal-mode assumes that the find-file function is calling it. In this case, it may process a local variables list at the end of the file and in the `-*-' line. The variable enable-local-variables controls whether to do so. See section `Local Variables in Files' in The GNU Emacs Manual, for the syntax of the local variables section of a file.

If you run normal-mode interactively, the argument find-file is normally nil. In this case, normal-mode unconditionally processes any local variables list.

normal-mode uses condition-case around the call to the major mode function, so errors are caught and reported as a `File mode specification error', followed by the original error message.



topUser Option: enable-local-variables
This variable controls processing of local variables lists in files being visited. A value of t means process the local variables lists unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is t.


topVariable: ignored-local-variables
This variable holds a list of variables that should not be set by a file's local variables list. Any value specified for one of these variables is ignored.


In addition to this list, any variable whose name has a non-nil risky-local-variable property is also ignored.

topUser Option: enable-local-eval
This variable controls processing of `Eval:' in local variables lists in files being visited. A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is maybe.


topFunction: set-auto-mode
This function selects the major mode that is appropriate for the current buffer. It may base its decision on the value of the `-*-' line, on the visited file name (using auto-mode-alist), on the `#!' line (using interpreter-mode-alist), or on the file's local variables list. However, this function does not look for the `mode:' local variable near the end of a file; the hack-local-variables function does that. See section `How Major Modes are Chosen' in The GNU Emacs Manual.


topUser Option: default-major-mode
This variable holds the default major mode for new buffers. The standard value is fundamental-mode.

If the value of default-major-mode is nil, Emacs uses the (previously) current buffer's major mode for the major mode of a new buffer. However, if that major mode symbol has a mode-class property with value special, then it is not used for new buffers; Fundamental mode is used instead. The modes that have this property are those such as Dired and Rmail that are useful only with text that has been specially prepared.



topFunction: set-buffer-major-mode buffer
This function sets the major mode of buffer to the value of default-major-mode. If that variable is nil, it uses the current buffer's major mode (if that is suitable).

The low-level primitives for creating buffers do not use this function, but medium-level commands such as switch-to-buffer and find-file-noselect use it whenever they create buffers.



topVariable: initial-major-mode
The value of this variable determines the major mode of the initial `*scratch*' buffer. The value should be a symbol that is a major mode command. The default value is lisp-interaction-mode.


topVariable: auto-mode-alist
This variable contains an association list of file name patterns (regular expressions; see section Regular Expressions) and corresponding major mode commands. Usually, the file name patterns test for suffixes, such as `.el' and `.c', but this need not be the case. An ordinary element of the alist looks like (regexp . mode-function).

For example,

(("\\`/tmp/fol/" . text-mode)
 ("\\.texinfo\\'" . texinfo-mode)
 ("\\.texi\\'" . texinfo-mode)
 ("\\.el\\'" . emacs-lisp-mode)
 ("\\.c\\'" . c-mode) 
 ("\\.h\\'" . c-mode)
 ...)

When you visit a file whose expanded file name (see section Functions that Expand Filenames) matches a regexp, set-auto-mode calls the corresponding mode-function. This feature enables Emacs to select the proper major mode for most files.

If an element of auto-mode-alist has the form (regexp function t), then after calling function, Emacs searches auto-mode-alist again for a match against the portion of the file name that did not match before. This feature is useful for uncompression packages: an entry of the form ("\\.gz\\'" function t) can uncompress the file and then put the uncompressed file in the proper mode according to the name sans `.gz'.

Here is an example of how to prepend several pattern pairs to auto-mode-alist. (You might use this sort of expression in your `.emacs' file.)

(setq auto-mode-alist
  (append 
   ;; File name (within directory) starts with a dot.
   '(("/\\.[^/]*\\'" . fundamental-mode)  
     ;; File name has no dot.
     ("[^\\./]*\\'" . fundamental-mode)   
     ;; File name ends in `.C'.
     ("\\.C\\'" . c++-mode))
   auto-mode-alist))
topVariable: interpreter-mode-alist
This variable specifies major modes to use for scripts that specify a command interpreter in an `#!' line. Its value is a list of elements of the form (interpreter . mode); for example, ("perl" . perl-mode) is one element present by default. The element says to use mode mode if the file specifies an interpreter which matches interpreter. The value of interpreter is actually a regular expression.

This variable is applicable only when the auto-mode-alist does not indicate which major mode to use.



topFunction: hack-local-variables &optional force
This function parses, and binds or evaluates as appropriate, any local variables specified by the contents of the current buffer.

The handling of enable-local-variables documented for normal-mode actually takes place here. The argument force usually comes from the argument find-file given to normal-mode.



top 24.1.4. Getting Help about a Major Mode

The describe-mode function is used to provide information about major modes. It is normally called with C-h m. The describe-mode function uses the value of major-mode, which is why every major mode function needs to set the major-mode variable.

topCommand: describe-mode
This function displays the documentation of the current major mode.

The describe-mode function calls the documentation function using the value of major-mode as an argument. Thus, it displays the documentation string of the major mode function. (See section Access to Documentation Strings.)



topVariable: major-mode
This variable holds the symbol for the current buffer's major mode. This symbol should have a function definition that is the command to switch to that major mode. The describe-mode function uses the documentation string of the function as the documentation of the major mode.


top 24.1.5. Defining Derived Modes

It's often useful to define a new major mode in terms of an existing one. An easy way to do this is to use define-derived-mode.

topMacro: define-derived-mode variant parent name docstring body...
This construct defines variant as a major mode command, using name as the string form of the mode name.

The new command variant is defined to call the function parent, then override certain aspects of that parent mode:

In addition, you can specify how to override other aspects of parent with body. The command variant evaluates the forms in body after setting up all its usual overrides, just before running variant-hook.

The argument docstring specifies the documentation string for the new mode. If you omit docstring, define-derived-mode generates a documentation string.

Here is a hypothetical example:

(define-derived-mode hypertext-mode
  text-mode "Hypertext"
  "Major mode for hypertext.
\\{hypertext-mode-map}"
  (setq case-fold-search nil))

(define-key hypertext-mode-map
  [down-mouse-3] 'do-hyper-link)

top next prev
24.2. Minor Modes

A minor mode provides features that users may enable or disable independently of the choice of major mode. Minor modes can be enabled individually or in combination. Minor modes would be better named "generally available, optional feature modes," except that such a name would be unwieldy.

A minor mode is not usually a modification of single major mode. For example, Auto Fill mode works with any major mode that permits text insertion. To be general, a minor mode must be effectively independent of the things major modes do.

A minor mode is often much more difficult to implement than a major mode. One reason is that you should be able to activate and deactivate minor modes in any order. A minor mode should be able to have its desired effect regardless of the major mode and regardless of the other minor modes in effect.

Often the biggest problem in implementing a minor mode is finding a way to insert the necessary hook into the rest of Emacs. Minor mode keymaps make this easier than it used to be.

top 24.2.1. Conventions for Writing Minor Modes

There are conventions for writing minor modes just as there are for major modes. Several of the major mode conventions apply to minor modes as well: those regarding the name of the mode initialization function, the names of global symbols, and the use of keymaps and other tables.

In addition, there are several conventions that are specific to minor modes.

You can also use add-to-list to add an element to this list just once (see section How to Alter a Variable Value).

top 24.2.2. Keymaps and Minor Modes

Each minor mode can have its own keymap, which is active when the mode is enabled. To set up a keymap for a minor mode, add an element to the alist minor-mode-map-alist. See section Active Keymaps.

One use of minor mode keymaps is to modify the behavior of certain self-inserting characters so that they do something else as well as self-insert. In general, this is the only way to do that, since the facilities for customizing self-insert-command are limited to special cases (designed for abbrevs and Auto Fill mode). (Do not try substituting your own definition of self-insert-command for the standard one. The editor command loop handles this function specially.)

The key sequences bound in a minor mode should consist of C-c followed by a punctuation character other than {, }, <, >, : or ;. (Those few punctuation characters are reserved for major modes.)

top 24.2.3. Easy-Mmode

The easy-mmode package provides a convenient way of implementing a minor mode; with it, you can specify all about a simple minor mode in one self-contained definition.

topMacro: easy-mmode-define-minor-mode mode doc &optional init-value mode-indicator keymap
This macro defines a new minor mode whose name is mode (a symbol).

This macro defines a command named mode which toggles the minor mode, and has doc as its documentation string.

It also defines a variable named mode, which is set to t or nil by enabling or disabling the mode. The variable is initialized to init-value.

The string mode-indicator says what to display in the mode line when the mode is enabled; if it is nil, the mode is not displayed in the mode line.

The optional argument keymap specifies the keymap for the minor mode. It can be a variable name, whose value is the keymap, or it can be an alist specifying bindings in this form:

(key-sequence . definition)

Here is an example of using easy-mmode-define-minor-mode:

(easy-mmode-define-minor-mode hungry-mode
  "Toggle Hungry mode.
With no argument, this command toggles the mode. 
Non-null prefix argument turns on the mode.
Null prefix argument turns off the mode.

When Hungry mode is enabled, the control delete key
gobbles all preceding whitespace except the last.
See the command \\[hungry-electric-delete]."
 ;; The initial value.
 nil
 ;; The indicator for the mode line.
 " Hungry"
 ;; The minor mode bindings.
 '(("\C-\^?" . hungry-electric-delete)
   ("\C-\M-\^?"
    . (lambda () 
        (interactive)
        (hungry-electric-delete t)))))

This defines a minor mode named "Hungry mode", a command named hungry-mode to toggle it, a variable named hungry-mode which indicates whether the mode is enabled, and a variable named hungry-mode-map which holds the keymap that is active when the mode is enabled. It initializes the keymap with key bindings for C-DEL and C-M-DEL.


top next prev
24.3. Mode Line Format

Each Emacs window (aside from minibuffer windows) includes a mode line, which displays status information about the buffer displayed in the window. The mode line contains information about the buffer, such as its name, associated file, depth of recursive editing, and the major and minor modes.

This section describes how the contents of the mode line are controlled. We include it in this chapter because much of the information displayed in the mode line relates to the enabled major and minor modes.

mode-line-format is a buffer-local variable that holds a template used to display the mode line of the current buffer. All windows for the same buffer use the same mode-line-format and their mode lines appear the same (except for scrolling percentages, and line and column numbers).

The mode line of a window is normally updated whenever a different buffer is shown in the window, or when the buffer's modified-status changes from nil to t or vice-versa. If you modify any of the variables referenced by mode-line-format (see section Variables Used in the Mode Line), or any other variables and data structures that affect how text is displayed (see section Emacs Display), you may want to force an update of the mode line so as to display the new information or display it in the new way.

topFunction: force-mode-line-update
Force redisplay of the current buffer's mode line.


The mode line is usually displayed in inverse video; see mode-line-inverse-video in section Inverse Video.

top 24.3.1. The Data Structure of the Mode Line

The mode line contents are controlled by a data structure of lists, strings, symbols, and numbers kept in the buffer-local variable mode-line-format. The data structure is called a mode line construct, and it is built in recursive fashion out of simpler mode line constructs. The same data structure is used for constructing frame titles (see section Frame Titles).

topVariable: mode-line-format
The value of this variable is a mode line construct with overall responsibility for the mode line format. The value of this variable controls which other variables are used to form the mode line text, and where they appear.


A mode line construct may be as simple as a fixed string of text, but it usually specifies how to use other variables to construct the text. Many of these variables are themselves defined to have mode line constructs as their values.

The default value of mode-line-format incorporates the values of variables such as mode-name and minor-mode-alist. Because of this, very few modes need to alter mode-line-format itself. For most purposes, it is sufficient to alter some of the variables that mode-line-format refers to.

A mode line construct may be a list, a symbol, or a string. If the value is a list, each element may be a list, a symbol, or a string.

topstring
A string as a mode line construct is displayed verbatim in the mode line except for %-constructs. Decimal digits after the `%' specify the field width for space filling on the right (i.e., the data is left justified). See section %-Constructs in the Mode Line.
topsymbol
A symbol as a mode line construct stands for its value. The value of symbol is used as a mode line construct, in place of symbol. However, the symbols t and nil are ignored; so is any symbol whose value is void. There is one exception: if the value of symbol is a string, it is displayed verbatim: the %-constructs are not recognized.
top(string rest...) or (list rest...)
A list whose first element is a string or list means to process all the elements recursively and concatenate the results. This is the most common form of mode line construct.
top(symbol then else)
A list whose first element is a symbol is a conditional. Its meaning depends on the value of symbol. If the value is non-nil, the second element, then, is processed recursively as a mode line element. But if the value of symbol is nil, the third element, else, is processed recursively. You may omit else; then the mode line element displays nothing if the value of symbol is nil.
top(width rest...)
A list whose first element is an integer specifies truncation or padding of the results of rest. The remaining elements rest are processed recursively as mode line constructs and concatenated together. Then the result is space filled (if width is positive) or truncated (to -width columns, if width is negative) on the right. For example, the usual way to show what percentage of a buffer is above the top of the window is to use a list like this: (-3 "%p").

If you do alter mode-line-format itself, the new value should use the same variables that appear in the default value (see section Variables Used in the Mode Line), rather than duplicating their contents or displaying the information in another fashion. This way, customizations made by the user or by Lisp programs (such as display-time and major modes) via changes to those variables remain effective.

Here is an example of a mode-line-format that might be useful for shell-mode, since it contains the host name and default directory.

(setq mode-line-format
  (list "-"
   'mode-line-mule-info
   'mode-line-modified
   'mode-line-frame-identification
   "%b--" 
   ;; Note that this is evaluated while making the list.
   ;; It makes a mode line construct which is just a string.
   (getenv "HOST")
   ":" 
   'default-directory
   "   "
   'global-mode-string
   "   %[("
   'mode-name 
   'mode-line-process  
   'minor-mode-alist 
   "%n" 
   ")%]--"
   '(which-func-mode ("" which-func-format "--"))
   '(line-number-mode "L%l--")
   '(column-number-mode "C%c--")
   '(-3 . "%p")
   "-%-"))

(The variables line-number-mode, column-number-mode and which-func-mode enable particular minor modes; as usual, these variable names are also the minor mode command names.)

top 24.3.2. Variables Used in the Mode Line

This section describes variables incorporated by the standard value of mode-line-format into the text of the mode line. There is nothing inherently special about these variables; any other variables could have the same effects on the mode line if mode-line-format were changed to use them.

topVariable: mode-line-mule-info
This variable holds the value of the mode-line construct that displays information about the language environment, buffer coding system, and current input method. See section Non-ASCII Characters.


topVariable: mode-line-modified
This variable holds the value of the mode-line construct that displays whether the current buffer is modified.

The default value of mode-line-modified is ("%1*%1+"). This means that the mode line displays `**' if the buffer is modified, `--' if the buffer is not modified, `%%' if the buffer is read only, and `%*' if the buffer is read only and modified.

Changing this variable does not force an update of the mode line.



topVariable: mode-line-frame-identification
This variable identifies the current frame. The default value is " " if you are using a window system which can show multiple frames, or "-%F " on an ordinary terminal which shows only one frame at a time.


topVariable: mode-line-buffer-identification
This variable identifies the buffer being displayed in the window. Its default value is ("%12b"), which displays the buffer name, padded with spaces to at least 12 columns.


topVariable: global-mode-string
This variable holds a mode line spec that appears in the mode line by default, just after the buffer name. The command display-time sets global-mode-string to refer to the variable display-time-string, which holds a string containing the time and load information.

The `%M' construct substitutes the value of global-mode-string, but that is obsolete, since the variable is included in the mode line from mode-line-format.



topVariable: mode-name
This buffer-local variable holds the "pretty" name of the current buffer's major mode. Each major mode should set this variable so that the mode name will appear in the mode line.


topVariable: minor-mode-alist
This variable holds an association list whose elements specify how the mode line should indicate that a minor mode is active. Each element of the minor-mode-alist should be a two-element list:

(minor-mode-variable mode-line-string)

More generally, mode-line-string can be any mode line spec. It appears in the mode line when the value of minor-mode-variable is non-nil, and not otherwise. These strings should begin with spaces so that they don't run together. Conventionally, the minor-mode-variable for a specific mode is set to a non-nil value when that minor mode is activated.

The default value of minor-mode-alist is:

minor-mode-alist
=> ((vc-mode vc-mode)
    (abbrev-mode " Abbrev") 
    (overwrite-mode overwrite-mode) 
    (auto-fill-function " Fill")         
    (defining-kbd-macro " Def")
    (isearch-mode isearch-mode))

minor-mode-alist itself is not buffer-local. Each variable mentioned in the alist should be buffer-local if its minor mode can be enabled separately in each buffer.



topVariable: mode-line-process
This buffer-local variable contains the mode line information on process status in modes used for communicating with subprocesses. It is displayed immediately following the major mode name, with no intervening space. For example, its value in the `*shell*' buffer is (":%s"), which allows the shell to display its status along with the major mode as: `(Shell: run)'. Normally this variable is nil.


topVariable: default-mode-line-format
This variable holds the default mode-line-format for buffers that do not override it. This is the same as (default-value 'mode-line-format).

The default value of default-mode-line-format is this list:

("-"
 mode-line-mule-info
 mode-line-modified
 mode-line-frame-identification
 mode-line-buffer-identification
 "   "
 global-mode-string
 "   %[("
 mode-name 
 mode-line-process
 minor-mode-alist 
 "%n" 
 ")%]--"
 (which-func-mode ("" which-func-format "--"))
 (line-number-mode "L%l--")
 (column-number-mode "C%c--")
 (-3 . "%p")
 "-%-")
topVariable: vc-mode
The variable vc-mode, buffer-local in each buffer, records whether the buffer's visited file is maintained with version control, and, if so, which kind. Its value is nil for no version control, or a string that appears in the mode line.


top 24.3.3. %-Constructs in the Mode Line

The following table lists the recognized %-constructs and what they mean. In any construct except `%%', you can add a decimal integer after the `%' to specify how many characters to display.

top%b
The current buffer name, obtained with the buffer-name function. See section Buffer Names.
top%f
The visited file name, obtained with the buffer-file-name function. See section Buffer File Name.
top%F
The title (only on a window system) or the name of the selected frame. See section Window Frame Parameters.
top%c
The current column number of point.
top%l
The current line number of point.
top%*
`%' if the buffer is read only (see buffer-read-only);
`*' if the buffer is modified (see buffer-modified-p);
`-' otherwise. See section Buffer Modification.
top%+
`*' if the buffer is modified (see buffer-modified-p);
`%' if the buffer is read only (see buffer-read-only);
`-' otherwise. This differs from `%*' only for a modified read-only buffer. See section Buffer Modification.
top%&
`*' if the buffer is modified, and `-' otherwise.
top%s
The status of the subprocess belonging to the current buffer, obtained with process-status. See section Process Information.
top%t
Whether the visited file is a text file or a binary file. (This is a meaningful distinction only on certain operating systems.)
top%p
The percentage of the buffer text above the top of window, or `Top', `Bottom' or `All'.
top%P
The percentage of the buffer text that is above the bottom of the window (which includes the text visible in the window, as well as the text above the top), plus `Top' if the top of the buffer is visible on screen; or `Bottom' or `All'.
top%n
`Narrow' when narrowing is in effect; nothing otherwise (see narrow-to-region in section Narrowing).
top%[
An indication of the depth of recursive editing levels (not counting minibuffer levels): one `[' for each editing level. See section Recursive Editing.
top%]
One `]' for each recursive editing level (not counting minibuffer levels).
top%%
The character `%'---this is how to include a literal `%' in a string in which %-constructs are allowed.
top%-
Dashes sufficient to fill the remainder of the mode line.

The following two %-constructs are still supported, but they are obsolete, since you can get the same results with the variables mode-name and global-mode-string.

top%m
The value of mode-name.
top%M
The value of global-mode-string. Currently, only display-time modifies the value of global-mode-string.

top next prev
24.4. Imenu

Imenu is a feature that lets users select a definition or section in the buffer, from a menu which lists all of them, to go directly to that location in the buffer. Imenu works by constructing a buffer index which lists the names and positions of the definitions or portions of in the buffer, so the user can pick one of them to move to. This section explains how to customize Imenu for a major mode.

The usual and simplest way is to set the variable imenu-generic-expression:

topVariable: imenu-generic-expression
This variable, if non-nil, specifies regular expressions for finding definitions for Imenu. In the simplest case, elements should look like this:

(menu-title regexp subexp)

Here, if menu-title is non-nil, it says that the matches for this element should go in a submenu of the buffer index; menu-title itself specifies the name for the submenu. If menu-title is nil, the matches for this element go directly in the top level of the buffer index.

The second item in the list, regexp, is a regular expression (see section Regular Expressions); wherever it matches, that is a definition to mention in the buffer index. The third item, subexp, indicates which subexpression in regexp matches the definition's name.

An element can also look like this:

(menu-title regexp index function arguments...)

Each match for this element creates a special index item which, if selected by the user, calls function with arguments item-name, the buffer position, and arguments.

For Emacs Lisp mode, pattern could look like this:

((nil "^\\s-*(def\\(un\\|subst\\|macro\\|advice\\)\
\\s-+\\([-A-Za-z0-9+]+\\)" 2)
 ("*Vars*" "^\\s-*(def\\(var\\|const\\)\
\\s-+\\([-A-Za-z0-9+]+\\)" 2)
 ("*Types*"
  "^\\s-*\
(def\\(type\\|struct\\|class\\|ine-condition\\)\
\\s-+\\([-A-Za-z0-9+]+\\)" 2))

Setting this variable makes it buffer-local in the current buffer.



topVariable: imenu-case-fold-search
This variable controls whether matching against imenu-generic-expression is case-sensitive: t, the default, means matching should ignore case.

Setting this variable makes it buffer-local in the current buffer.



topVariable: imenu-syntax-alist
This variable is an alist of syntax table modifiers to use while processing imenu-generic-expression, to override the syntax table of the current buffer. Each element should have this form:

(characters . syntax-description)

The CAR, characters, can be either a character or a string. The element says to give that character or characters the syntax specified by syntax-description, which is passed to modify-syntax-entry (see section Syntax Table Functions).

This feature is typically used to give word syntax to characters which normally have symbol syntax, and thus to simplify imenu-generic-expression and speed up matching. For example, Fortran mode uses it this way:

  (setq imenu-syntax-alist '(("_$" . "w")))

The imenu-generic-expression patterns can then use `\\sw+' instead of `\\(\\sw\\|\\s_\\)+'. Note that this technique may be inconvenient to use when the mode needs to limit the initial character of a name to a smaller set of characters than are allowed in the rest of a name.

Setting this variable makes it buffer-local in the current buffer.



Another way to customize Imenu for a major mode is to set the variables imenu-prev-index-position-function and imenu-extract-index-name-function:

topVariable: imenu-prev-index-position-function
If this variable is non-nil, its value should be a function for finding the next definition to mention in the buffer index, moving backwards in the file.

The function should leave point at the place to be connected to the index item; it should return nil if it doesn't find another item.

Setting this variable makes it buffer-local in the current buffer.



topVariable: imenu-extract-index-name-function
If this variable is non-nil, its value should be a function to return the name for a definition, assuming point is in that definition as the imenu-prev-index-position-function function would leave it.

Setting this variable makes it buffer-local in the current buffer.



The last way to customize Imenu for a major mode is to set the variables imenu-create-index-function:

topVariable: imenu-create-index-function
This variable specifies the function to use for creating a buffer index. The function should take no arguments, and return an index for the current buffer. It is called within save-excursion, so where it leaves point makes no difference.

The default value is a function that uses imenu-generic-expression to produce the index alist. If you specify a different function, then imenu-generic-expression is not used.

Setting this variable makes it buffer-local in the current buffer.



topVariable: imenu-index-alist
This variable holds the index alist for the current buffer. Setting it makes it buffer-local in the current buffer.

Simple elements in the alist look like (index-name . index-position). Selecting a simple element has the effect of moving to position index-position in the buffer.

Special elements look like (index-name position function arguments...). Selecting a special element performs

(funcall function index-name position arguments...)

A nested sub-alist element looks like (index-name sub-alist).




top next prev
24.5. Font Lock Mode

Font Lock mode is a feature that automatically attaches face properties to certain parts of the buffer based on their syntactic role. How it parses the buffer depends on the major mode; most major modes define syntactic criteria for which faces to use, in which contexts. This section explains how to customize Font Lock for a particular language--in other words, for a particular major mode.

Font Lock mode finds text to highlight in two ways: through syntactic parsing based on the syntax table, and through searching (usually for regular expressions). Syntactic fontification happens first; it finds comments and string constants, and highlights them using font-lock-comment-face and font-lock-string-face (see section Faces for Font Lock); search-based fontification follows.

top 24.5.1. Font Lock Basics

There are several variables that control how Font Lock mode highlights text. But major modes should not set any of these variables directly. Instead, it should set font-lock-defaults as a buffer-local variable. The value assigned to this variable is used, if and when Font Lock mode is enabled, to set all the other variables.

topVariable: font-lock-defaults
This variable is set by major modes, as a buffer-local variable, to specify how to fontify text in that mode. The value should look like this:

(keywords keywords-only case-fold
 syntax-alist syntax-begin other-vars...)

The first element, keywords, indirectly specifies the value of font-lock-keywords. It can be a symbol, a variable whose value is list to use for font-lock-keywords. It can also be a list of several such symbols, one for each possible level of fontification. The first symbol specifies how to do level 1 fontification, the second symbol how to do level 2, and so on.

The second element, keywords-only, specifies the value of the variable font-lock-keywords-only. If this is non-nil, syntactic fontification (of strings and comments) is not performed.

The third element, case-fold, specifies the value of font-lock-case-fold-search. If it is non-nil, Font Lock mode ignores case when searching as directed by font-lock-keywords.

If the fourth element, syntax-alist, is non-nil, it should be a list of cons cells of the form (char-or-string . string). These are used to set up a syntax table for fontification (see section Syntax Table Functions). The resulting syntax table is stored in font-lock-syntax-table.

The fifth element, syntax-begin, specifies the value of font-lock-beginning-of-syntax-function (see below).

Any further elements other-vars are have form (variable . value). This kind of element means to make variable buffer-local and then set it to value. This is used to set other variables that affect fontification.



top 24.5.2. Search-based Fontification

The most important variable for customizing Font Lock mode is font-lock-keywords. It specifies the search criteria for search-based fontification.

topVariable: font-lock-keywords
This variable's value is a list of the keywords to highlight. Be careful when composing regular expressions for this list; a poorly written pattern can dramatically slow things down!


Each element of font-lock-keywords specifies how to find certain cases of text, and how to highlight those cases. Font Lock mode processes the elements of font-lock-keywords one by one, and for each element, it finds and handles all matches. Ordinarily, once part of the text has been fontified already, this cannot be overridden by a subsequent match in the same text; but you can specify different behavior using the override element of a highlighter.

Each element of font-lock-keywords should have one of these forms:

topregexp
Highlight all matches for regexp using font-lock-keyword-face. For example,
;; Highlight discrete occurrences of `foo'
;; using font-lock-keyword-face.
"\\<foo\\>"
The function regexp-opt (see section Syntax of Regular Expressions) is useful for calculating optimal regular expressions to match a number of different keywords.
topfunction
Find text by calling function, and highlight the matches it finds using font-lock-keyword-face. When function is called, it receives one argument, the limit of the search. It should return non-nil if it succeeds, and set the match data to describe the match that was found.
top(matcher . match)
In this kind of element, matcher stands for either a regular expression or a function, as described above. The CDR, match, specifies which subexpression of matcher should be highlighted (instead of the entire text that matcher matched).
;; Highlight the `bar' in each occurrences of `fubar',
;; using font-lock-keyword-face.
("fu\\(bar\\)" . 1)
If you use regexp-opt to produce the regular expression matcher, then you can use regexp-opt-depth (see section Syntax of Regular Expressions) to calculate the value for match.
top(matcher . facename)
In this kind of element, facename is an expression whose value specifies the face name to use for highlighting.
;; Highlight occurrences of `fubar',
;; using the face which is the value of fubar-face.
("fubar" . fubar-face)
top(matcher . highlighter)
In this kind of element, highlighter is a list which specifies how to highlight matches found by matcher. It has the form
(subexp facename override laxmatch)
The CAR, subexp, is an integer specifying which subexpression of the match to fontify (0 means the entire matching text). The second subelement, facename, specifies the face, as described above. The last two values in highlighter, override and laxmatch, are flags. If override is t, this element can override existing fontification made by previous elements of font-lock-keywords. If it is keep, then each character is fontified if it has not been fontified already by some other element. If it is prepend, the face facename is added to the beginning of the face property. If it is append, the face facename is added to the end of the face property. If laxmatch is non-nil, it means there should be no error if there is no subexpression numbered subexp in matcher. Here are some examples of elements of this kind, and what they do:
;; Highlight occurrences of either `foo' or `bar',
;; using foo-bar-face, even if they have already been highlighted.
;; foo-bar-face should be a variable whose value is a face.
("foo\\|bar" 0 foo-bar-face t)

;; Highlight the first subexpression within each occurrences
;; that the function fubar-match finds,
;; using the face which is the value of fubar-face.
(fubar-match 1 fubar-face)
top(matcher highlighters...)
This sort of element specifies several highlighter lists for a single matcher. In order for this to be useful, each highlighter should have a different value of subexp; that is, each one should apply to a different subexpression of matcher.
top(eval . form)
Here form is an expression to be evaluated the first time this value of font-lock-keywords is used in a buffer. Its value should have one of the forms described in this table.

Warning: Do not design an element of font-lock-keywords to match text which spans lines; this does not work reliably. While font-lock-fontify-buffer handles multi-line patterns correctly, updating when you edit the buffer does not, since it considers text one line at a time.

top 24.5.3. Other Font Lock Variables

This section describes additional variables that a major mode can set by means of font-lock-defaults.

topVariable: font-lock-keywords-only
Non-nil means Font Lock should not fontify comments or strings syntactically; it should only fontify based on font-lock-keywords.


topVariable: font-lock-keywords-case-fold-search
Non-nil means that regular expression matching for the sake of font-lock-keywords should be case-insensitive.


topVariable: font-lock-syntax-table
This variable specifies the syntax table to use for fontification of comments and strings.


topVariable: font-lock-beginning-of-syntax-function
If this variable is non-nil, it should be a function to move point back to a position that is syntactically at "top level" and outside of strings or comments. Font Lock uses this when necessary to get the right results for syntactic fontification.

This function is called with no arguments. It should leave point at the beginning of any enclosing syntactic block. Typical values are beginning-of-line (i.e., the start of the line is known to be outside a syntactic block), or beginning-of-defun for programming modes or backward-paragraph for textual modes (i.e., the mode-dependent function is known to move outside a syntactic block).

If the value is nil, the beginning of the buffer is used as a position outside of a syntactic block. This cannot be wrong, but it can be slow.



topVariable: font-lock-mark-block-function
If this variable is non-nil, it should be a function that is called with no arguments, to choose an enclosing range of text for refontification for the command M-g M-g (font-lock-fontify-block).

The function should report its choice by placing the region around it. A good choice is a range of text large enough to give proper results, but not too large so that refontification becomes slow. Typical values are mark-defun for programming modes or mark-paragraph for textual modes.



top 24.5.4. Levels of Font Lock

Many major modes offer three different levels of fontification. You can define multiple levels by using a list of symbols for keywords in font-lock-defaults. Each symbol specifies one level of fontification; it is up to the user to choose one of these levels. The chosen level's symbol value is used to initialize font-lock-keywords.

Here are the conventions for how to define the levels of fontification:

top 24.5.5. Faces for Font Lock

You can make Font Lock mode use any face, but several faces are defined specifically for Font Lock mode. Each of these symbols is both a face name, and a variable whose default value is the symbol itself. Thus, the default value of font-lock-comment-face is font-lock-comment-face. This means you can write font-lock-comment-face in a context such as font-lock-keywords where a face-name-valued expression is used.

topfont-lock-comment-face
Used (typically) for comments.
topfont-lock-string-face
Used (typically) for string constants.
topfont-lock-keyword-face
Used (typically) for keywords--names that have special syntactic significance, like for and if in C.
topfont-lock-builtin-face
Used (typically) for built-in function names.
topfont-lock-function-name-face
Used (typically) for the name of a function being defined or declared, in a function definition or declaration.
topfont-lock-variable-name-face
Used (typically) for the name of a variable being defined or declared, in a variable definition or declaration.
topfont-lock-type-face
Used (typically) for names of user-defined data types, where they are defined and where they are used.
topfont-lock-constant-face
Used (typically) for constant names.
topfont-lock-warning-face
Used (typically) for constructs that are peculiar, or that greatly change the meaning of other text. For example, this is used for `;;;###autoload' cookies in Emacs Lisp, and for #error directives in C.

top 24.5.6. Syntactic Font Lock

Font Lock mode can be used to update syntax-table properties automatically. This is useful in languages for which a single syntax table by itself is not sufficient.

topVariable: font-lock-syntactic-keywords
This variable enables and controls syntactic Font Lock. Its value should be a list of elements of this form:

(matcher subexp syntax override laxmatch)

The parts of this element have the same meanings as in the corresponding sort of element of font-lock-keywords,

(matcher subexp facename override laxmatch)

However, instead of specifying the value facename to use for the face property, it specifies the value syntax to use for the syntax-table property. Here, syntax can be a variable whose value is a syntax table, a syntax entry of the form (syntax-code . matching-char), or an expression whose value is one of those two types.




top prev
24.6. Hooks

A hook is a variable where you can store a function or functions to be called on a particular occasion by an existing program. Emacs provides hooks for the sake of customization. Most often, hooks are set up in the `.emacs' file, but Lisp programs can set them also. See section Standard Hooks, for a list of standard hook variables.

Most of the hooks in Emacs are normal hooks. These variables contain lists of functions to be called with no arguments. When the hook name ends in `-hook', that tells you it is normal. We try to make all hooks normal, as much as possible, so that you can use them in a uniform way.

Every major mode function is supposed to run a normal hook called the mode hook as the last step of initialization. This makes it easy for a user to customize the behavior of the mode, by overriding the buffer-local variable assignments already made by the mode. But hooks are used in other contexts too. For example, the hook suspend-hook runs just before Emacs suspends itself (see section Suspending Emacs).

The recommended way to add a hook function to a normal hook is by calling add-hook (see below). The hook functions may be any of the valid kinds of functions that funcall accepts (see section What Is a Function?). Most normal hook variables are initially void; add-hook knows how to deal with this.

If the hook variable's name does not end with `-hook', that indicates it is probably an abnormal hook; you should look at its documentation to see how to use the hook properly.

If the variable's name ends in `-functions' or `-hooks', then the value is a list of functions, but it is abnormal in that either these functions are called with arguments or their values are used in some way. You can use add-hook to add a function to the list, but you must take care in writing the function. (A few of these variables are actually normal hooks which were named before we established the convention of using `-hook' for them.)

If the variable's name ends in `-function', then its value is just a single function, not a list of functions.

Here's an example that uses a mode hook to turn on Auto Fill mode when in Lisp Interaction mode:

(add-hook 'lisp-interaction-mode-hook 'turn-on-auto-fill)

At the appropriate time, Emacs uses the run-hooks function to run particular hooks. This function calls the hook functions that have been added with add-hook.

topFunction: run-hooks &rest hookvar
This function takes one or more hook variable names as arguments, and runs each hook in turn. Each hookvar argument should be a symbol that is a hook variable. These arguments are processed in the order specified.

If a hook variable has a non-nil value, that value may be a function or a list of functions. If the value is a function (either a lambda expression or a symbol with a function definition), it is called. If it is a list, the elements are called, in order. The hook functions are called with no arguments. Nowadays, storing a single function in the hook variable is semi-obsolete; you should always use a list of functions.

For example, here's how emacs-lisp-mode runs its mode hook:

(run-hooks 'emacs-lisp-mode-hook)
topFunction: run-hook-with-args hook &rest args
This function is the way to run an abnormal hook which passes arguments to the hook functions. It calls each of the hook functions, passing each of them the arguments args.


topFunction: run-hook-with-args-until-failure hook &rest args
This function is the way to run an abnormal hook which passes arguments to the hook functions, and stops as soon as any hook function fails. It calls each of the hook functions, passing each of them the arguments args, until some hook function returns nil. Then it stops, and returns nil if some hook function did, and otherwise returns a non-nil value.


topFunction: run-hook-with-args-until-success hook &rest args
This function is the way to run an abnormal hook which passes arguments to the hook functions, and stops as soon as any hook function succeeds. It calls each of the hook functions, passing each of them the arguments args, until some hook function returns non-nil. Then it stops, and returns whatever was returned by the last hook function that was called.


topFunction: add-hook hook function &optional append local
This function is the handy way to add function function to hook variable hook. The argument function may be any valid Lisp function with the proper number of arguments. For example,

(add-hook 'text-mode-hook 'my-text-hook-function)

adds my-text-hook-function to the hook called text-mode-hook.

You can use add-hook for abnormal hooks as well as for normal hooks.

It is best to design your hook functions so that the order in which they are executed does not matter. Any dependence on the order is "asking for trouble." However, the order is predictable: normally, function goes at the front of the hook list, so it will be executed first (barring another add-hook call). If the optional argument append is non-nil, the new hook function goes at the end of the hook list and will be executed last.

If local is non-nil, that says to make the new hook function buffer-local in the current buffer. Before you can do this, you must make the hook itself buffer-local by calling make-local-hook (not make-local-variable). If the hook itself is not buffer-local, then the value of local makes no difference--the hook function is always global.



topFunction: remove-hook hook function &optional local
This function removes function from the hook variable hook.

If local is non-nil, that says to remove function from the buffer-local hook list instead of from the global hook list. If the hook variable itself is not buffer-local, then the value of local makes no difference.



topFunction: make-local-hook hook
This function makes the hook variable hook buffer-local in the current buffer. When a hook variable is buffer-local, it can have buffer-local and global hook functions, and run-hooks runs all of them.

This function works by making t an element of the buffer-local value. That serves as a flag to use the hook functions in the default value of the hook variable as well as those in the buffer-local value. Since run-hooks understands this flag, make-local-hook works with all normal hooks. It works for only some non-normal hooks--those whose callers have been updated to understand this meaning of t.

Do not use make-local-variable directly for hook variables; it is not sufficient.




   Search    TOC: Show / Hide

   Indexes: Functions / Variables / Commands / Forms / Options / Macros / Keywords / Misc

   Next: Documentation   Previous: Keymaps